@echo off 

:: --- ПРОВЕРКА ПРАВ АДМИНИСТРАТОРА ---
:: Проверяем наличие прав администратора через команду net session
net session >nul 2>&1
if %ERRORLEVEL% NEQ 0 (
    echo ERROR: This script must be run as ADMINISTRATOR.
    echo Please right-click the file and select "Run as administrator".
    pause
    exit /b
)

:: --- УКАЖИТЕ ЗНАЧЕНИЯ ПЕРЕМЕННЫХ ---
:: Укажите полную версию 1С (например, 8.3.27.2074)
set Version=8.3.XX.XXXX

:: Укажите порт сервера администрирования (по умолчанию 1545) 
set PortRAS=1545

:: Укажите адрес и порт агента сервера 1С к которому будет подключаться RAS (по умолчанию localhost:1540)
set MonitoredServerAgent=localhost:1540

:: Укажите имя пользователя для запуска службы RAS
set RasUserName=имя_пользователя

:: Укажите пароль пользователя
set RasUserPwd=пароль_пользователя

:: --- ПАРАМЕТРЫ ДЛЯ СЛУЖБЫ ---
:: Техническое имя службы
set SrvcName="1C_RAS_%Version%"

:: Отображаемое имя в списке служб Windows
set Desctiption="1C:Enterprise 8.3 RAS (%Version%) Parameters: port: %PortRAS%, monitored server: %MonitoredServerAgent%"

:: Полная команда запуска с параметрами
set BinPath="\"C:\Program Files\1cv8\%Version%\bin\ras.exe\" cluster --service --port=%PortRAS% %MonitoredServerAgent%"

:: --- ПРОВЕРКА НАЛИЧИЯ СЛУЖБЫ ---
:: Проверяем, не установлена ли служба ранее
sc query %SrvcName% >nul 2>&1
if %ERRORLEVEL% EQU 0 (
    echo Service %SrvcName% is already installed. Nothing to do.
    pause
    exit /b
)

:: --- УСТАНОВКА ---
echo Installing service %SrvcName%...

:: Создание службы. ВАЖНО: пробел после знака "=" обязателен!
sc create %SrvcName% binPath= %BinPath% start= auto obj= %RasUserName% password= %RasUserPwd% displayname= %Desctiption%

:: Проверка результата создания
if %ERRORLEVEL% EQU 0 (
    echo Service created successfully.
	sc description %SrvcName% %Desctiption%
    echo Starting service...
    sc start %SrvcName%
) else (
    echo ERROR: Failed to create service. Check parameters or permissions.
)

:: Ожидание нажатия клавиши перед закрытием окна
Pause